VERSION 1.0 CLASS
BEGIN
  MultiUse = -1  'True
END
Attribute VB_Name = "CWaitCursor"
Attribute VB_GlobalNameSpace = False
Attribute VB_Creatable = True
Attribute VB_PredeclaredId = False
Attribute VB_Exposed = False
'----------------------------------------
'- Name: Sam Huggill
'- Email: sam@vbsquare.com
'- Web: http://www.vbsquare.com/
'- Company: Lighthouse Internet Solutions
'- Date/Time: 14/08/99 11:25:57
'----------------------------------------
'- Notes:   The class automatically resets the
'           mouse pointer when a procedure
'           exits
'----------------------------------------

Option Explicit

Private mlPointer As MousePointerConstants

Private Sub Class_Initialize()
    mlPointer = Screen.MousePointer
End Sub

Private Sub Class_Terminate()
    Restore
End Sub

Public Sub SetCursor(Optional nPointer As MousePointerConstants = vbHourglass)
    Screen.MousePointer = nPointer
End Sub

Public Sub Restore()
    Screen.MousePointer = mlPointer
End Sub


